! Beams on elastic foundations - Winkler


/prep7


!Input data

L_g=15		! length of the beam		[m]
gg=2		! thickness of the beam 	[m]
lg=1		! width of the beam		[m]

a=1.5		! length from the left side of the beam to the point of force/ moment application			[m]
b=L_g-a		!													[m]
c=3		! length from the left side of the beam to the starting point of uniform loading from water weight	[m]
d=L_g-c		!													[m]

E_b=21000000	! E of the beam material - concrete			[kN/m^2]
u_b=0.2		! Poisson coefficient for beam material - concrete
G_b=2.4		! Unit mass of the beam material - concrete		[t/m^3] 


k=50000		! Modulus of the foundation


P=500		! Concentrated force from the wall weight - a is point of application 	[kN]
M=150		! Concentrated moment							[kNm]
wp=10		! pressure from the weight of the water in the lock 			[kN/m]
sp=-20		! Uplift pressure							[kN/m]				


! geometry elements

I_g=lg*gg*gg*gg/12
A_g=gg*lg
hyt=gg/2
hyb=gg/2

! Element type 

ET,1,beam54		

! Real constants

!*  
*SET,_RC_SET,1, 
R,_RC_SET,A_g,I_g,hyt,hyb, 
RMODIF,_RC_SET,5,A_g,I_g,hyt,hyb,
RMODIF,_RC_SET,9, , ,   
RMODIF,_RC_SET,11, , ,  
RMODIF,_RC_SET,13, ,
RMODIF,_RC_SET,14, ,
RMODIF,_RC_SET,15, ,
RMODIF,_RC_SET,16,k, , ,   
!* 

! Material properties - for the beam

MP,EX,1,E_b
MP,prxy,1,u_b
MP,dens,1,G_b

! Nodes

n,1,0,0
n,4,a,0
n,7,c,0
n,27,d,0
n,30,b,0
n,33,L_g,0

fill,1,4,2,2,1
fill,4,7,2,5,1
fill,7,27,19,8,1
fill,27,30,2,28,1
fill,30,33,2,31,1

! Elements

e,1,2
egen,32,1,1

! Loadings

ACEL,0,9.81,0, 		!Gravity - weight of the beam

F,4,FY,-P
F,30,FY,-P

F,4,MZ,-M
F,30,MZ,M

Esel,s,elem,,7,26,1
SFbeam,all,1,pres,wp+sp
eall

Esel,s,elem,,1,6,1
Esel,a,elem,,27,33,1
SFbeam,all,1,pres,sp
eall

/solu
solve

/post1

esel,s,mat,1,1,1

etab,ti,smisc,2
etab,tj,smisc,8

etab,mi,smisc,6
etab,mj,smisc,12

plns,u,y		!displacement

! plls,ti,tj		!shear force diagram
! plls,mi,mj		!moment diagram